
    ReqServerSentEvents

Req plugin for Server-Sent
Events
(SSE).
Decodes chunked SSE byte streams into %ReqServerSentEvents.Frame{} structs, transparently
wrapping all three of Req's streaming hooks: into: fun, into: :self, and
into: collectable.

Installation
def deps do
  [
    {:req, "~> 0.5"},
    {:req_server_sent_events, "~> 0.2.4"}
  ]
end
Usage
Attach the plugin to any %Req.Request{} with ReqServerSentEvents.attach/1. It rewrites
the into: option in place so that each complete SSE frame is decoded to a
%ReqServerSentEvents.Frame{} before reaching your handler.
into: must be set on the request before calling attach/1 — pass it to Req.new/1,
not to Req.get/2.
Options
attach/2 accepts an options keyword list:
	Option	Type	Description
	:max_frame_size	pos_integer() | nil	Cap on the pending-frame buffer. If the buffer grows past this many bytes without a "\n\n" delimiter, a ReqServerSentEvents.FrameTooLargeError is raised. Defaults to nil (unbounded).

Req.new(url: url, into: [])
|> ReqServerSentEvents.attach(max_frame_size: 1_048_576)
|> Req.get!()
into: collectable
Decoded frames are collected into any Collectable. The request blocks until
the server closes the connection, making this best suited for finite streams.
{:ok, resp} =
  Req.new(url: "https://example.com/events", into: [])
  |> ReqServerSentEvents.attach()
  |> Req.get()

frames = resp.body  # [%ReqServerSentEvents.Frame{}, ...]
into: fun
Your function receives {:sse_event, %ReqServerSentEvents.Frame{}} instead of
{:data, binary}. Return {:cont, {req, resp}} to continue or
{:halt, {req, resp}} to stop early.
Req.new(
  url: "https://example.com/events",
  into: fn {:sse_event, frame}, {req, resp} ->
    IO.inspect(frame)
    {:cont, {req, resp}}
  end
)
|> ReqServerSentEvents.attach()
|> Req.get!()
into: :self
Decoded frames are sent to the calling process as {ref, {:sse_event, %Frame{}}}.
A {ref, :sse_done} sentinel is sent when the stream ends. Retrieve the ref with
ReqServerSentEvents.ref/1.
Note: self() is captured when attach/1 is called. Call attach/1 in
the same process that will receive the messages — typically inside a
Task.async callback as shown below.

task = Task.async(fn ->
  Req.new(url: "https://example.com/events", into: :self)
  |> ReqServerSentEvents.attach()
  |> Req.get!()
end)

resp = Task.await(task)
ref = ReqServerSentEvents.ref(resp)
For short-lived or finite streams, a plain receive is sufficient:
receive do
  {^ref, {:sse_event, frame}} -> IO.inspect(frame)
  {^ref, :sse_done}           -> :done
after
  30_000 -> :timeout
end
For unbounded streams, wrap the receive in a Stream.resource/3:
Stream.resource(
  fn -> ref end,
  fn ref ->
    receive do
      {^ref, {:sse_event, frame}} -> {[frame], ref}
      {^ref, :sse_done}           -> {:halt, ref}
    after
      30_000 -> {:halt, ref}
    end
  end,
  fn _ -> :ok end
)
|> Enum.each(&IO.inspect/1)
Frame fields
Each decoded event is a %ReqServerSentEvents.Frame{} struct:
	Field	Type	Description
	event	String.t() | nil	Event type (event: field)
	data	String.t() | nil	Payload; multiple data: lines joined with "\n"
	id	String.t() | nil	Event ID for Last-Event-ID reconnect header
	retry	non_neg_integer() | nil	Reconnection delay in milliseconds
	comments	[String.t()]	Lines starting with : (keepalive, diagnostics)

Frames with no data: field (e.g. comment-only keepalives) are passed through
to the handler — filter or discard them as needed.
The id and retry fields follow the SSE reconnection protocol: retry is the
server-suggested delay in milliseconds before reconnecting, and id should be sent
as the Last-Event-ID request header on reconnect. This library decodes both
fields but does not implement automatic reconnection — that is the caller's
responsibility.
Reconnection example
A minimal into: fun consumer that tracks the most recent id and retry,
then reconnects with Last-Event-ID after the suggested delay:
defmodule SSEReconnectExample do
  alias ReqServerSentEvents.Frame

  @default_retry 3_000

  def stream(url, last_id \\ nil) do
    headers = if last_id, do: [{"last-event-id", last_id}], else: []

    {:ok, resp} =
      Req.new(url: url, headers: headers, into: &handle_event/2)
      |> ReqServerSentEvents.attach()
      |> Req.get()

    last_id = resp.private[:last_id] || last_id
    retry_ms = resp.private[:retry] || @default_retry
    Process.sleep(retry_ms)
    stream(url, last_id)
  end

  defp handle_event({:sse_event, %Frame{} = frame}, {req, resp}) do
    resp =
      resp
      |> maybe_put_private(:last_id, frame.id)
      |> maybe_put_private(:retry, frame.retry)

    # ... process frame.data here ...

    {:cont, {req, resp}}
  end

  defp maybe_put_private(resp, _key, nil), do: resp
  defp maybe_put_private(resp, key, value), do: put_in(resp.private[key], value)
end
Wrap the recursive stream/2 call in a Task (or supervised GenServer) so it
survives independent of the calling process, and add your own error handling for
non-2xx responses, transport failures, and graceful shutdown.
Development
Requirements: Elixir ~> 1.17, Erlang/OTP compatible with your Elixir version.
# Install dependencies
mix deps.get

# Run tests
mix test

# Run unit tests only (skips Bypass integration tests for a faster loop)
mix test --exclude integration

# Run tests with coverage
mix coveralls.html

# Format code
mix format

# Check formatting without writing
mix format --check-formatted

Tests do not require a running server. The plugin's streaming logic is exercised
by calling the rewritten into: handlers directly with synthetic byte chunks.
The integration tests in test/req_server_sent_events_integration_test.exs use
Bypass to spin up a local HTTP server.
They can be excluded with mix test --exclude integration for a faster feedback loop.


  

    Changelog

All notable changes to this project will be documented in this file.
The format is based on Keep a Changelog,
and this project adheres to Semantic Versioning.
0.2.4 (2026-09-18)
Bug Fixes
	deps: bump req from 0.7.3 to 0.7.4 (#29) (b60fc0e)

0.2.3 (2026-08-29)
Bug Fixes
	deps: bump req from 0.6.2 to 0.7.2 (#24) (9e2cf73)
	deps: bump req from 0.7.2 to 0.7.3 (#27) (5acb64e)

0.2.2 (2026-07-18)
Bug Fixes
	deps: bump req from 0.5.18 to 0.6.1 (#15) (e849ed1)
	deps: bump req from 0.6.1 to 0.6.2 (#18) (852ffc6)

0.2.1 (2026-06-14)
Bug Fixes
	deps: bump req from 0.5.17 to 0.5.18 (#6) (f73ce0f)
	frame: handle bare CR as line terminator in parse/1 (001f4da)
	frame: restore single-pattern split fast path for LF buffers (c90dce1)

Performance Improvements
	frame: split on multi-pattern delimiters without normalising (926d4a0)

0.2.0 (2026-05-03)
Features
	plugin: add :max_frame_size option to attach/2 (5a089cf)
	plugin: emit telemetry events for streams and frames (cafd0f1)

Bug Fixes
	frame: align parser with SSE spec (c3b0c5a)
	frame: normalise CRLF line endings and fix O(n²) comment accumulation (2b5e609)
	plugin: populate sse_ref on response in sse_done step (4e43c6e)
	resolve credo strict nesting depth violation in wrap_fun (af13935)

0.1.0 (2026-04-30)
Initial release.

Req plugin for Server-Sent Events (SSE).
Attach to any %Req.Request{} via attach/1. The plugin intercepts
Req's three streaming hooks and transparently decodes raw SSE byte chunks
into %ReqServerSentEvents.Frame{} structs.
Usage
# into: fun — frames delivered as {:sse_event, %Frame{}} arguments
url
|> Req.new(into: fn {:sse_event, frame}, {req, resp} ->
     IO.inspect(frame)
     {:cont, {req, resp}}
   end)
|> ReqServerSentEvents.attach()
|> Req.get!()

# into: :self — frames sent as messages to the calling process
task = Task.async(fn ->
  url
  |> Req.new(into: :self)
  |> ReqServerSentEvents.attach()
  |> Req.get!()
end)
resp = Task.await(task)
sse_ref = ReqServerSentEvents.ref(resp)
receive do
  {^sse_ref, {:sse_event, frame}} -> IO.inspect(frame)
  {^sse_ref, :sse_done}           -> :done
end

# into: collectable — frames collected into any Collectable
{:ok, resp} =
  url
  |> Req.new(into: [])
  |> ReqServerSentEvents.attach()
  |> Req.get()
frames = resp.body  # [%ReqServerSentEvents.Frame{}, ...]
Telemetry
The plugin emits the following :telemetry events:
	[:req_server_sent_events, :stream, :start] — emitted on the first
decoded chunk of an into: fun or into: :self request.
Measurements: %{system_time, monotonic_time}. Metadata: %{request: req}.

	[:req_server_sent_events, :frame, :decoded] — emitted once per
decoded frame in any mode.
Measurements: %{bytes: byte_size(raw)}. Metadata: %{frame: frame}.

	[:req_server_sent_events, :stream, :stop] — emitted in a response
step when an into: fun or into: :self stream ends. Only fires if
:start fired (i.e. at least one chunk was processed).
Measurements: %{monotonic_time, duration}. Metadata: %{request: req, response: resp}.


:start and :stop are not emitted for into: collectable requests —
the wrapper has no access to the response. For stream-level timing in that
mode, use Req's own [:req, :request, :start | :stop] events.

        attach(req, opts \\ [])

      


        Attach the SSE decoder to a %Req.Request{}.



    


    
      
        ref(req)

      


        Return the SSE ref for a into: :self request.

          @spec attach(Req.Request.t(), keyword()) :: Req.Request.t()


      


Attach the SSE decoder to a %Req.Request{}.
Rewrites req.into to decode raw SSE byte chunks into
%ReqServerSentEvents.Frame{} structs before they reach the caller.
When into: :self is used, also registers a response step that sends
a {ref, :sse_done} sentinel once the stream closes.
Options
	:max_frame_size — maximum number of bytes allowed to accumulate in
the pending-frame buffer between delimiters. If the buffer grows past
this limit without seeing a "\n\n", a
ReqServerSentEvents.FrameTooLargeError is raised. Defaults to nil
(unbounded).

          @spec ref(Req.Request.t() | Req.Response.t()) :: reference() | nil


      


Return the SSE ref for a into: :self request.
Accepts either the final %Req.Request{} or %Req.Response{} — Req's
high-level functions (Req.get!/2 etc.) return only the response, while
Req.request/2 returns {request, response}.

Wraps any Collectable so that raw SSE byte chunks are decoded into
%ReqServerSentEvents.Frame{} structs before being collected.
The byte buffer is carried in the accumulator alongside the inner
collectable's own accumulator, so no process state is required.
Partial frames at end-of-stream are discarded — a frame is only
emitted once terminated by "\n\n".

Pure SSE frame parser. No IO, no processes, no external dependencies.
An SSE frame is a sequence of field: value lines terminated by a blank line (\n\n).
Recognised fields: event, data, id, retry. Lines starting with : are comments.
Multiple data: lines within one frame are concatenated with "\n".

    Functions
  


    
      
        parse(raw)

      


        Parse one complete raw frame string (without the trailing "\n\n") into a %Frame{}.



    


    
      
        split(buffer)

      


        Split a byte buffer on the SSE frame delimiter.

          @type t() :: %ReqServerSentEvents.Frame{
  comments: [String.t()],
  data: String.t() | nil,
  event: String.t() | nil,
  id: String.t() | nil,
  retry: non_neg_integer() | nil
}

          @spec parse(binary()) :: t()


      


Parse one complete raw frame string (without the trailing "\n\n") into a %Frame{}.
Frames with no data: field are returned as-is — the caller decides whether to
dispatch or discard them. Unknown field names are silently ignored per the SSE spec.
Examples
iex> ReqServerSentEvents.Frame.parse("event: ping\ndata: {}")
%ReqServerSentEvents.Frame{event: "ping", data: "{}"}

iex> ReqServerSentEvents.Frame.parse(": keepalive")
%ReqServerSentEvents.Frame{comments: ["keepalive"]}

          @spec split(binary()) :: {[binary()], binary()}


      


Split a byte buffer on the SSE frame delimiter.
Recognises "\n\n", "\r\n\r\n", and "\r\r" as frame
delimiters per SSE spec §9.2.4. Returned frame strings retain their
original line endings; parse/1 handles all three terminator forms.
A leading UTF-8 byte order mark ("\uFEFF") is stripped per the spec.
Returns {complete_frames, leftover} where complete_frames is a list of raw
frame strings (without the trailing delimiter) and leftover is the remaining
bytes that have not yet formed a complete frame.
Examples
iex> ReqServerSentEvents.Frame.split("data: hello\n\n")
{["data: hello"], ""}

iex> ReqServerSentEvents.Frame.split("data: hello\r\n\r\n")
{["data: hello"], ""}

iex> ReqServerSentEvents.Frame.split("data: partial")
{[], "data: partial"}

  


        

      


  

    
ReqServerSentEvents.FrameTooLargeError exception
    



      
Raised when the SSE byte buffer grows past the configured :max_frame_size
without encountering a frame delimiter ("\n\n").

          @type t() :: %ReqServerSentEvents.FrameTooLargeError{
  __exception__: true,
  limit: pos_integer(),
  size: non_neg_integer()
}

